home *** CD-ROM | disk | FTP | other *** search
/ 17 Bit Software 3: The Continuation / 17-Bit_The_Continuation_Disc.iso / amigan / amigan 17 / qman / msmooth.asm < prev    next >
Assembly Source File  |  1994-01-27  |  6KB  |  149 lines
  1. ****************************************************************************
  2. *
  3. *         Draws a Row of Pixels in Mandelbrot Set (with smoothing)
  4. *
  5. *         C must set the following variables prior to call:
  6. * 
  7. *                xptr   :  pointer to table of x-values 
  8. *                imagc  :  imaginary part of current pixel row
  9. *                bp1-4  :  pointers to the four bit planes
  10. *  
  11. *         Integers are 2**26 times the actual values in the complex plane
  12. *
  13. ****************************************************************************
  14.  
  15. *  First some macros we will need.....
  16.  
  17. EvalPix     MACRO
  18.             moveq       #79,d3               set counter to 79
  19.             clr.l       d0                   zero out real_z
  20.             clr.l       d2                   zero out imag_z
  21.  
  22. repeat\1    moveq       #13,d7               number of bits to shift
  23.             asr.l       d7,d0                divide real_z by 2**13
  24.             asr.l       d7,d2                divide imag_z by 2**13
  25.  
  26.             move.l      d0,d1                real_z
  27.             sub.w       d2,d0                real_z - imag_z
  28.             add.w       d1,d1                2 * real_z
  29.             muls        d1,d2                2 * real_z * imag_z
  30.             sub.w       d0,d1                real_z + imag_z
  31.             muls        d1,d0                real_z**2 - imag_z**2
  32.            
  33.             add.l       d5,d0                add real_c to get new real_z
  34.             move.l      d0,d7                create temp copy of real_z
  35.             bpl         pos_1\1              if real_z positive, do nothing
  36.             neg.l       d7                   take absolute value of real_z
  37. pos_1\1     add.l       d6,d2                add imag_c to get new imag_z
  38.             move.l      d2,d1                load working copy of imag_z
  39.             bpl         pos_2\1              if imag_z positive, do nothing
  40.             neg.l       d1                   take absolute value of imag_z
  41. pos_2\1     add.l       d1,d7                d7 contains the norm of z
  42.             subq        #1,d3                decrement counter by 1
  43.             beq         pixout\1             if 79 iters, draw the pixel
  44.             subi.l      #200000000,d7        reduce the norm by 200 million 
  45.             bmi         repeat\1             if z not exploding, continue
  46.             addq        #1,d3                increment counter by 1
  47.             asr.l       #3,d3                color is 1/8 number of iters
  48.             addq        #3,d3                range 3 to 12
  49. pixout\1    nop
  50.             ENDM
  51.  
  52. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
  53.  
  54. WritePix    MACRO
  55.             tst.l       d4                   examine bit within byte
  56.             bne         plane1\1             if not bit zero, poke planes
  57.             moveq       #8,d4                reset to bit 8 (next will be 7)
  58.             lea         1(a0),a0             incr addr within 1st bit plane
  59.             lea         1(a1),a1                              2nd
  60.             lea         1(a2),a2                              3rd
  61.             lea         1(a3),a3                              4th
  62. plane1\1    subq.l      #1,d4                decrement bit within byte by 1
  63.  
  64. nomenus\1   btst        d4,(a0)              if we've hit a menu-- STOP!
  65.             bne         nomenus\1 
  66.             btst        d4,(a1)
  67.             bne         nomenus\1
  68.             btst        d4,(a2)
  69.             bne         nomenus\1
  70.             btst        d4,(a3)
  71.             bne         nomenus\1
  72.  
  73.             btst        #0,d3                examine 1st bit of color
  74.             beq         plane2\1             if bit off, leave screen alone
  75.             bset        d4,(a0)              turn current bit on in plane
  76. plane2\1    btst        #1,d3              
  77.             beq         plane3\1
  78.             bset        d4,(a1)
  79. plane3\1    btst        #2,d3
  80.             beq         plane4\1
  81.             bset        d4,(a2)
  82. plane4\1    btst        #3,d3
  83.             beq         writeout\1
  84.             bset        d4,(a3)
  85. writeout\1  nop
  86.             ENDM
  87.  
  88. *------------------------------------------*
  89. *           The main routine!              *
  90. *------------------------------------------*
  91.  
  92.             XDEF        _msmooth             This tells C about us
  93.             SECTION     text,code
  94.  
  95. _msmooth    movem.l     d2-d7/a2-a6,-(a7)    save registers
  96. setup       moveq       #8,d4                bit within screen byte
  97.             move.l      #638,pixct           pixel counter for current row
  98.             move.l      _xptr,a5              
  99.             move.l      _imagc,d6
  100.             move.l      _bp1,a0              
  101.             move.l      _bp2,a1
  102.             move.l      _bp3,a2
  103.             move.l      _bp4,a3
  104.   
  105. xloop       move.l      (a5),d5              move next x-value into D5
  106.  
  107.             EvalPix     0                    the i-th pixel
  108.             move.l      d3,lastval 
  109.             WritePix    0
  110.  
  111.             adda        #8,a5
  112.             move.l      (a5),d5
  113.             EvalPix     2                    the (i+2)nd pixel
  114.             move.l      d3,nextval
  115.             suba        #4,a5
  116.             
  117.             cmp         lastval,d3
  118.             beq         nextpix
  119.             
  120.             move.l      (a5),d5
  121.             EvalPix     1                    the (i+1)st pixel
  122.  
  123. nextpix     WritePix    1                         
  124.             move.l      nextval,d3
  125.             WritePix    2
  126.  
  127.             adda        #8,a5
  128.  
  129. next_x      subi.l      #3,pixct             decrement x counter
  130.             bpl         xloop                if not done with row, continue
  131.  
  132.             add.l       #80,_bp1             advance to next display line
  133.             add.l       #80,_bp2
  134.             add.l       #80,_bp3
  135.             add.l       #80,_bp4
  136.  
  137.             movem.l     (a7)+,d2-d7/a2-a6    restore registers
  138.           
  139.             rts
  140.  
  141.             SECTION     udata,bss      
  142.             XREF        _xptr,_imagc
  143.             XREF        _bp1,_bp2,_bp3,_bp4
  144. pixct       DS.L        1
  145. lastval     DS.L        1
  146. nextval     DS.L        1
  147.             END
  148.  
  149.